Bessel Functions, Fin Temperature,

Heat Transfer Rate and Resistance

M.M. Yovanovich

PROJ981BESS.MWS

Modified Bessel functions with Maple.

How to call and evaluate the four modified Bessel functions which appear in the temperature distribution and heat flow rate expressions for circular annular fins.

Calculation of fin heat transfer rate and the fin resistance.

> restart:

Modified Bessel functions and .

> BesselI(0,1.5); BesselI(1,1.5);

Modified Bessel functions and .

> BesselK(0,1.5); BesselK(1,1.5);

Temperature distribution in a circular annular fin.

> theta:= thetab*Numer/Denom;

> Numer:= BesselI(0, m*r)*BesselK(1, m*r2) + BesselK(0, m*r)*BesselI(1, m*r2);

> Denom:= BesselI(0, m*r1)*BesselK(1, m*r2) + BesselK(0, m*r1)*BesselI(1, m*r2);

Define the fin parameter .

> m:= sqrt(2*h/(k*t));

Here we define a list of system parameters: inner and outer radii, r1 and r2, fin thickness t, thermal conductivity k, heat transfer coefficient h, and the temperature excess at the fin base, thetab.

> syspar:= (r1 = 5/1000, r2 = 20/1000, h = 15, t = 2/1000, k = 80, thetab = 100);

Substitute the system parameters into the temperature distribution.

> theta_fin:= evalf(subs(syspar, theta), 6);

Plot of the temperature distribution.

> plot(theta_fin, r =5/1000..20/1000);

We see that the temperature difference changes slowly from the base of the fin to the tip of the fin.

Fin Resistance.

> Rfin:= thetab/Qfin;

Heat Flow Rate.

> m:='m':
Qfin:= 2*Pi*k*r1*t*m*thetab*Num2/Denom2;

> Num2:= BesselK(1,m*r1)*BesselI(1,m*r2) - BesselI(1,m*r1)*BesselK(1,m*r2);

> Denom2:= BesselK(0,m*r1)*BesselI(1,m*r2) + BesselI(0,m*r1)*BesselK(1,m*r2);

> m:= sqrt(2*h/(k*t));

Calculate the heat transfer rate for the system parameters given above.

> Qfinval:= evalf(subs(syspar, Qfin), 5)*W;

Calculation of fin resistance.

> Rfin:= evalf(subs(syspar, Rfin), 5)*K/W;

The heat transfer rate and the fin thermal resistance have been computed for a circular annular fin with adiabatic tip. To account for cooling at the tip it is recommended that the outer radius r2 be replaced by a corrected outer radius r2c where r2c = r2 + t/2.