Half-Space Robin Problems

M.M. Yovanovich

HSROBIN1.MWS

Robin half-space solution. Applications to several different problems where one of the several system parameters are found given the remaining parameters.

This requires a numerical inversion of the Robin solution when one of the parameters, for example, are not given. This worksheet shows the usefulness of a Computer Algebra System such as Maple

> restart:

> Robin:= T - (Ti + (Tf-Ti)*(erfc(x/(2*sqrt(alpha*t))) - exp(h*x/k + h^2*alpha*t/k^2)*erfc(x/(2*sqrt(alpha*t)) + h*sqrt(alpha*t)/k)));

Solve for the surface temperature.

> case1:= (Tf=400, Ti=300, h=300, k=50, alpha=3e-6, x=0, t=100);

> T1:= fsolve(subs(case1, Robin),T);

Solve for heat transfer coefficient .

> case2:= (Tf=400, Ti=300, T = 310.7, k=50, alpha=3e-6, x=0, t=100);

> h2:= fsolve(subs(case2, Robin),h);

Solve for thermal conductivity .

> case3:= (Tf=400, Ti=300, T = 310.7, h=500, alpha=3e-6, x=0, t=100);

> k3:= fsolve(subs(case3, Robin),k);

Solve for thermal diffusivity .

> case4:= (Tf=400, Ti=300, T = 310, h=500, k= 84, x=10/1000, t=100);

> alpha4:= fsolve(subs(case4, Robin),alpha, 0..1e-2);

Maple appears to have difficulties with this case.

Solve for position in the half-space .

> case5:= (Tf=500, Ti=300, T = 310, h=500, k= 80, alpha=3e-6, t=100);

> x5:= fsolve(subs(case5,Robin),x)*1000;

Solve for the fluid temperature .

> case6:= (x=14/1000, Ti=300, T = 310, h=500, k= 80, alpha=3e-6, t=100);

> Tf6:= fsolve(subs(case6,Robin),Tf);

Solve for the initial temperature .

> case7:= (x=14/1000, Tf=500, T = 310, h=500, k= 80, alpha=3e-6, t=100);

> Ti7:= fsolve(subs(case7,Robin),Ti);

The above six examples illustrate how the Robin solution can be used to find the unknown parameters when the remaining parameters are known.