ME 353 Heat Transfer 1

M.M. Yovanovich

NC2CYL1.MWS

_______________________________________

Natural convection in annular space bounded by

two horizontal, concentric, isothermal cylinders.

The inner and outer diameters and temperatures

are: Di, Do and Ti, To, respectively.

Fluid properties are based on the mean value

of the inner and outer surface temperatures.

The expression for the effective thermal conductivity

of the fluid in the annular space is valid for the

range 10^2 <= Racstar <= 10^7. For Racstar < 100,

keff/kf = 1.

_________________________________________

> restart:

System parameters and fluid properties.

Dry air properties at Tf = (Ti + To)/2 = 330 K.

> syspar:=
(g = 9.81, Di = 20/1000, Do = 40/1000, Ti = 360, To = 300);

> airprops:=
(kf = 0.0287, rho = 1.073, cp = 1006, mu = 19.713-6,
nu = 18.37*10^(-6), alpha = (18.37/.69)*10^(-6),
Pr = 0.69, beta = 1/330);

Raithby-Hollands (1975) correlation equation.

> Q_per_length:= 2*Pi*keff/(ln(Do/Di))*(Ti - To);
#Eq.(9.58)

> keff:= 0.386*kf*(Pr/(0.861 + Pr))^(1/4)*Racstar^(1/4);
#Eq. (9.59)

> Racstar:= (ln(Do/Di))^4/L^3/(Di^(-3/5) + Do^(-3/5))^5*RaL;
#Eq. (9.60)

> RaL:= g*beta*(Ti - To)*L^3/(alpha*nu);
#Not defined in the 4th edition

> L:= (Do - Di)/2; #See Fig. 9.14

The heat transfer per unit length expression.

> Q_per_length:= Q_per_length;

Observe that L does not appear in the above expression

and further that ln(Do/Di) can be cancelled from the expression.

The expression can be written in the following form:

> Q_per_length:=
0.772*Pi*kf*(Pr/(0.861 + Pr))^(1/4)/
(1 + (Di/Do)^(3/5))^(5/4)*(g*beta*
(Ti - To)*Di^3/(alpha*nu))^(1/4)*(Ti - To);

The dimensionless parameter which remains is the Rayleigh

number which is based on the diameter of the inner cylinder.

The relation can be written in terms of the Nusselt number

based on the inner diameter NuDi = Q_per_length Di/(pi Di kf (Ti - To))

and the Rayleigh number.

We note that Di cancels and the relation for NuDi becomes:

> NuDi:= 0.772*(Pr/(0.861 + Pr))^(1/4)/
(1 + (Di/Do)^(3/5))^(5/4)*RaDi^(1/4);

> RaDi:= g*beta*(Ti - To)*Di^3/(alpha*nu);

Computation of the parameters.

> RaL1:=
evalf(subs(airprops, syspar, RaL), 5);

> Racstar1:=
evalf(subs(airprops, syspar, Racstar), 5);

> RaDi1:=
evalf(subs(airprops, syspar, RaDi), 5);

> keff1:=
evalf(subs(airprops, syspar, airprops, keff), 5);

> Q_per_length1:=
evalf(subs(airprops, syspar, Q_per_length), 5);

The flow within the annular space is laminar.

The relationships given above can be used to calculate

another case such as Example 9.5 from 4th edition of

Incropera and DeWitt. The fluid is air at Tf = 350 K.

The diameters are Di = 120 mm and Do = 120 mm.

Note that the space is filled with air and glass-fiber;

therefore, Incropera and DeWitt used a conductivity

equal to the conductivity of the fiber-glass.

> exp9p5:=
(g = 9.81, kf = 0.030, nu = 20.92e-6, alpha = 29.9e-6,
Pr = 0.70, beta = 0.00285);

> exp9p5par:=
(Di = 100/1000, Do = 120/1000, Ti = 120 + 273, To = 35 + 273);

> RaL2:=
evalf(subs(exp9p5, exp9p5par, RaL), 6);

> Racstar2:=
evalf(subs(exp9p5, exp9p5par, Racstar), 6);

> RaDi2:=
evalf(subs(exp9p5, exp9p5par, RaDi), 6);

> keff2:=
evalf(subs(exp9p5, exp9p5par, airprops, keff), 6);

> Q_per_length2:=
evalf(subs(exp9p5, exp9p5par, Q_per_length), 6);

The calculated values agree with the values reported in the text.

The heat transfer rate per unit length with fiber-glass is

obtained from the conduction relationship.

> Q_per_length3:=
evalf(subs(Di = 100/1000, Do = 120/1000, k = 0.0380,
Ti = 120, To = 35, 2*Pi*k/ln(Do/Di)*(Ti - To)), 4);

>