Example 9.4 of Incropera and DeWitt

M.M. Yovanovich

EX9P4.MWS

Example 9.4 of 4th edition of Incropera and DeWitt.

> restart:

Air properties at 367 K.

> airprops:= (k=0.0313, nu=22.8e-6,alpha=32.8e-6,Pr=0.697, beta=1/367);

System parameters.

> syspar:= (g=9.81, sigma=5.67e-8, epsilon=0.85, Dia=0.1, epsilon=0.85, Ts=165, Tf=23, Tsurr=23);

Heat loss per unit length of pipe by convection and radiation.

> Q:= Qconv + Qrad;

> Qconv:= h*A1*(Ts-Tf);

> Qrad:= epsilon*sigma*A1*((Ts+273)^4 - (Tsurr+273)^4);

> A1:= Pi*Dia;

> h:= k*NuD/Dia;

Churchill correlation equation for horizontal isothermal cylinder.

> NuD:= (0.6 + 0.387*RaD^(1/6)/(1+(0.559/Pr)^(9/16))^(8/27))^2:

> RaD:= g*beta*(Ts-Tf)*Dia^3/(alpha*nu);

> beta:= 1/(Tf+273);

Calculations.

> Q1:= evalf(subs(airprops, syspar, A=A1, Q),5);

> RaD1:= evalf(subs(airprops, syspar, RaD),5);

> NuD1:= evalf(subs(airprops, syspar, NuD),5);

> h1:= evalf(subs(airprops, syspar, h),5);

> Qconv1:= evalf(subs(airprops, syspar, A=A1, Qconv),5);

> Qrad1:= evalf(subs(airprops, syspar, A=A1, Qrad),5);

The convection and radiation contributions are comparable.

Find the effect of a layer of insulation on heat loss.

The conduction through the insulation is equal to the heat loss from the outer surface of the insulation by convection and radiation.

> HeatBalance:= Qins-Qconv2-Qrad2=0:

> Qins:= 2*Pi*kins*(T1-T2)/ln(r2/r1);

> inspar:= (kins=0.026, r1=0.05, r2=0.05+0.025, Ts=T2, T1=165);

> A2:= Pi*D2; D2:= 0.15;

Calculate the surface temperature of the insulation.

> Qconv2:= subs(Dia=0.15, Ts=T2, Qconv):

> Qrad2:= subs(Dia=0.15, Ts=T2, Qrad):

> HeatBalance:= Qins-Qconv2-Qrad2=0:

> fsolve(subs(airprops, syspar, inspar, T1=Ts, A=A2, HeatBalance), T2, 0..200);

The insulation has reduced the outer surface temperature to 35.65 degrees C.

> Qconv2:= evalf(subs(airprops, syspar, T2=35.654, Qconv2),4);

> Qrad2:= evalf(subs(airprops, syspar, T2=35.654, Qrad2),4);

> Qloss2:= Qconv2+Qrad2;

The insulation has reduced the convective and radiative losses significantly.