ME 353 Heat Transfer 1

M.M. Yovanovich

EX3P10.MWS

Example 3.10 of 4th edition of Fundamentals of Heat Transfer and

Mass Transfer, F.P. Incropera and D.P. DeWitt, 1996.

The approach taken in this Maple Worksheet is based on the concept

of component resistances and the equivalent thermal circuit.

> restart:

System resistance and system heat flow rate.

> Qsystem:= (Tb - Tf)/Rtotal;

> Rtotal:= Rcont + Rcyl + 1/(1/Rbare + 1/Rfins);

Component resistances.

> Rcont:= 1/(hc*2*Pi*r1*H);

> Rcyl:= ln(r2/r1)/(2*Pi*k*H);

> Rbare:= 1/(h*Abare);

Fins are in parallel arrangement.

> Rfins:= Rfin/Nfins;

> Rfin:=
(1 + (h/m/k)*tanh(m*L))/(tanh(m*L) + (h/m/k))/M;

See Eq. (3.72) and Table 3.4. Remove (Tb - Tf) from M.

Fin and system parameters.

> M:= sqrt(h*P*k*A); m:= sqrt((h*P)/(k*A));

> P:= 2*(H + t); A:= t*H;
Abare:= (2*Pi*r2 - t*Nfins)*H;

Set the system parameters, then compute the component resistances, the total

resistance, and the system heat flow rate.

> case1:= (r1 = 2/1000, r2 = 3/1000, L = 10/1000,
t = 0.7/1000, H = 6/1000,
Nfins = 12, k = 200, hc = 1000, h = 25,
Tb = 80, Tf = 20);

List of component thermal resistances.

> resistances:=
[Rcont, Rcyl, Rbare, Rfin, Rfins, Rtotal]:

Contact resistance.

> R[cont]:=
evalf(subs(case1, resistances[1]), 4)*K/W;

Cylindrical wall resistance.

> R[cyl]:=
evalf(subs(case1, resistances[2]), 4)*K/W;

Unfinned (bare) surface resistance.

> R[bare]:=
evalf(subs(case1, resistances[3]), 4)*K/W;

Single fin resistance.

> R[fin]:=
evalf(subs(case1, resistances[4]), 4)*K/W;

Resistance of fin array.

> R[fins]:=
evalf(subs(case1, resistances[5]), 4)*K/W;

System resistance.

> R[total]:=
evalf(subs(case1, resistances[6]), 4)*K/W;

System heat transfer rate.

> Q[system]:=
evalf(subs(case1, Qsystem), 4)*W;