ME 353 Heat Transfer 1

M.M. Yovanovich

EX1P3.MWS

Example 1.3 of 4th edition of Incropera and DeWitt.

Derive relation for instantaneous temperature rise for a rod of diameter and length . The electrical resistance per unit length is , the current flow is amperes. Heat loss from the surface of the rod is by convection and radiation to its surroundings.

> restart:

Assumptions.

1. At any instant of time, the temperature of the rod cross-section is uniform but it varies with time: T(t).

2. All properties are assumed to be constant during the heat process.

3. Radiation exchange is between a body and its surroundings.

4. For calculations assume a unit length of rod.

Heat balance.

> HeatBalance:= Qgen - Qconv - Qrad;

Heat generation rate by ohmic heating.

> Qgen:= Current^2*Re_per_L*L;

Convective heat loss.

> Qconv:= h*Pi*D*L*(T(t) - Tinfty);

Radiative heat loss.

> Qrad:= epsilon*sigma*Pi*D*L*(T(t)^4 - Tsur^4);

Energy storage rate.

> Qstorage:= rho*cp*Pi*D^2/4*L*Diff(T(t),t);

> HeatBalance = Qstorage;

> eq1:= Diff(T(t),t) = solve(%, Diff(T(t),t));

We have obtained the relation between the time rate of change of the rod temperature as a function of the ohmic heating, and the convective and radiative heat losses. Numerical methods are required to find the solution for given system parameters.

Maple can be used to calculate values of the steady-state temperature for currents from 1 to 10 amperes for the system parameters given by Incropera and DeWitt.

> syspar:= (D = 1/1000, Re_per_L = 0.4, epsilon = 0.8, sigma = 5.67e-8, h = 100, Tinfty = 300, Tsur = 300);

Steady state temperature. and .

> eq2:= subs(T(t) = Tss, eq1);

> eq3:= numer(subs(syspar, rhs(eq2))) = 0;

We have obtained the equation which relates the steady-state rod temperature as a function of the electrical current.

The current for safe operation lie in the range: . It can be solve to find the surface temperature for different currents.

Surface temperature for 1 ampere.

> rts1:= solve(subs(Current = 1, eq3), Tss);

Maple returns four roots: 2 real and 2 complex. The positive real root is for 1 ampere.

> Tss1:= evalf(rts1[2] - 273, 4)*C;

Surface temperature for 5.2 amperes.

> rts4:= solve(subs(Current = 5.2, eq3), Tss);

> Tss4:= evalf(rts4[2] - 273, 4)*C;

Surface temperature for 10 amperes.

> rts10:= solve(subs(Current = 10, eq3), Tss);

> Tss10:= evalf(rts10[2] - 273, 4)*C;

Calculation of a list of values of the steady-state temperature for currents of 1 to 10 amperes.

> Tssvals:= evalf([seq(solve(subs(Current = j, eq3), Tss)[2]-273, j=1..10)],4);

The computed values of the surface temperature can be compared to the values shown in the figure on page 17.