ME 353 Heat Transfer 1

M.M. Yovanovich

EXP13P5.MWS

Example 13.5 of 4th edition of Fundamentals of Heat Transfer and

Mass Transfer by Incropera and DeWitt, 1996.

Assumptions:

1. Surfaces are diffuse and gray.

2. Spa ce between tubes is evacuated.

3. Radiation shield is very thin and has high conductvity;

its conduction resistance is negligible.

4. Concentric tubes form a long, two-dimensional enclosure.

> restart:

System parameters without and with shield

> sys_without:=
(D1 = 20/1000, D2 = 50/1000, epsilon1 = 0.02, epsilon2 = 0.05, T1 = 77, T2 = 300, sigma = 5.67e-8);

> sys_with:=
(D1 = 20/1000, D2 = 50/1000, D3 = 35/1000, epsilon1 = 0.02, epsilon2 = 0.05, epsilon3 = 0.02, T1 = 77, T2 = 300, sigma = 5.67e-8);

Heat transfer rate per unit length of tube

> Qsys:= (Eb1 - Eb2)/Rsys;
Eb1:= sigma*T1^4; Eb2:= sigma*T2^4;

Radiative resistance of the system without and with shield

> Rsys_wo:= Rs1 + R12 + Rs2;

> Rsys_w:= Rs1 + R13 + Rs31 + Rs32 + R32 + Rs2;

> Rs1:= (1 - epsilon1)/(A1*epsilon1);
Rs2:= (1 - epsilon2)/(A2*epsilon2);
Rs31:= (1 - epsilon3)/(A3*epsilon3);
Rs32:= (1 - epsilon3)/(A3*epsilon3);
R12:= 1/(A1*F12); R13:= 1/(A1*F13); R32:= 1/(A3*F32);
F12:= 1; F13:= 1; F32:= 1;

Geometric parameters per unit length

> A1:= Pi*D1; A2:= Pi*D2; A3:= Pi*D3;

Computation of the radiative resistances without and with shield

> Rsys1:= evalf(subs(sys_without, Rsys_wo), 5);

> Rsys2:= evalf(subs(sys_with, Rsys_w), 5);

Computation of heat transfer rates without and with shield

> Qsys1:= evalf(subs(Rsys = Rsys1, sys_without, Qsys), 5);

> Qsys2:= evalf(subs(Rsys = Rsys2, sys_with, Qsys), 5);

Percent change in the heat gain

> percent_change:= evalf((Qsys2 - Qsys1)/Qsys1*100, 4);

The percent change in the heat gain is approximately - 50%.