ME 353 Heat Transfer 1

M.M. Yovanovich

CARTPOS2.MWS

___________________________________________

Solution of Poisson Equation in Plate With Convective

Cooling at the Boundaries. Applications to several

problems.

The symbolic Maple output for this general solution is quite

long and not very informative; therefore it will be suppressed.

Only the most important results will be shown.

If you wish to see a result such as the temperature,

change T: to T;

The general will be used to obtain a few particular solutions

by setting the system input parameters which are:

x, L, k, P, h1, h2, Tf1, Tf2.

The general solution provides the following results (outputs):

1) T, the temperature distribution;

2) T0 and TL, the surface temperatures at x = 0 and x = L;

3) xmax, the location where the maximum temperature occurs;

4) Tmax, the maximum temperature;

5) Q0, the heat transfer rate through the boundary x = 0;

5) QL, the heat transfer rate through the boundary x = L.

**********************************************************************

For example we will examine the following cases:

1) h1 = 0 (adiabatic boundary), h2 > 0.

2) Bi1 = h1 L/k = 1, Bi2 = h2 L/k = 10, Tf1 > Tf2;

3) Bi1 = Bi2, Tf1 = Tf2, symmetry case;

_________________________________________________

> restart:

> ode:= diff(T(x), x$2) = - P/k;

> sol:= dsolve(ode, T(x));

The temperature distribution.

> T:= rhs(sol);

The derivative of the temperature distribution.

> derT:= diff(T, x);

> bc1:=
k*subs(x = 0, derT) = h1*(subs(x = 0, T) - Tf1);

> bc2:=
- k*subs(x = L, derT) = h2*(subs(x = L, T) - Tf2);

Constants of integration.

> consts:= solve({bc1, bc2}, {_C1, _C2}):

> assign(consts):

The general temperature distribution.

> T:

Surface temperature at x = 0.

> T0:= subs(x = 0, T):

Surface temperature at x = L.

> TL:= subs(x = L, T):

Determine the location of the maximum temperature which occurs where

the temperature gradient is zero. Call the location xmax.

Verify that the maximum temperature occurs at the midpoint when

Tf1 = Tf2 and h1 = h2.

> xmax:= expand(solve(derT = 0, x)):

> x_mid_point:=
simplify(subs(Tf1 = Tf2, h1 = h2, xmax));

Obtain expressions for the heat transfer rates at the two boundaries x = 0

and x = L. Call these heat flow rates Q0 and QL respectively.

Find the sum of Q0 and QL.

> Q[0]:= expand(k*A*subs(x = 0, diff(rhs(sol), x))):

> Q[L]:= expand(- k*A*subs(x = L, diff(rhs(sol), x))):

> energy_balance:= Q[0] + Q[L];

Obtain the general expression for the maximum temperature.

> Tmax:= subs(x = xmax, T):

The following examples illustrate how the general solution and general results

can be used to obtain particular solutions.

Case1: The left boundary is adiabatic and all heat generated is conducted through the right boundary into the fluid at temperature Tf2.

> case1:= (h1 = 0):

> temp1:= simplify(subs(case1, T));

> T01:= expand(subs(case1, T0));

> TL1:= expand(subs(case1, TL));

> xmax1:= expand(subs(case1, xmax));

The maximum temperature occurs at adiabatic boundary.

> Tmax1:= expand(subs(case1, Tmax));

> simplify(T01 - Tmax1); #T01 = Tmax1.

Left boundary is adiabatic.

> Q01:= expand(subs(case1, Q[0]));

> QL1:= expand(subs(case1, Q[L]));

Case2: Bi1 = h1 L/k = 1, Bi2 = h2 L/k = 10, Tf1 > Tf2.

> case2:=
(A = 1, h1 = 1, h2 = 10, k = 1, L = 1, Tf1 = 330,
Tf2 = 300, P = 500);

> temp2:= expand(subs(case2, T));

> T02:= evalf(expand(subs(case2, T0)), 5);

> TL2:= evalf(expand(subs(case2, TL)), 5);

> xmax2:= expand(subs(case2, xmax));

> Tmax2:= evalf(expand(subs(case2, Tmax)), 5);

> Q02:= evalf(subs(case2, Q[0]), 5);

> QL2:= evalf(subs(case2, Q[L]), 5);

> Qgen2:= evalf(subs(case2, P*A*L), 5);

Case 3: Symmetry where h1 = h2, Tf1 = Tf2.

> case3:=
(A = 1, h1 = 100, h2 = 100, k = 30, L = 0.10,
Tf1 = 300, Tf2 = 300, P = 2e5);

> temp3:= expand(subs(case3, T));

> T03:= evalf(expand(subs(case3, T0)), 5);

> TL3:= evalf(expand(subs(case3, TL)), 5);

> xmax3:= expand(subs(case3, xmax));

> Tmax3:= evalf(expand(subs(case3, Tmax)), 5);

> Q03:= evalf(subs(case3, Q[0]), 6);

> QL3:= evalf(subs(case3, Q[L]), 6);

> Qgen3:= evalf(subs(case3, P*A*L), 5);

>