ME 353 Heat Transfer 1

M.M. Yovanovich

CARTPOS1.MWS

_________________________________________________

Solution of Poisson Equation in Plane Wall With Convective

Cooling at the Both Boundaries.

Obtain the temperature distribution T(x), and the temperatures

at the two boundaries T(x = 0) and T(x = L).

Obtain the heat transfer rates from the two boundaries into

the respective heat sinks. Check the heat balance.

Find the location of the temperature maximum.

Find the maximum temperature.

__________________________________________________

> restart:

> ode:= diff(T(x), x$2) = - P/k;

> sol:=
dsolve(ode, T(x));
T:= rhs(sol);
derT:= diff(T, x);

> bc1:=
k*subs(x = 0, derT) = h1*(subs(x = 0, T) - Tf1);

> bc2:=
- k*subs(x = L, derT) = h2*(subs(x = L, T) - Tf2);

> consts:= solve({bc1, bc2}, {_C1, _C2}):

> assign(consts):

The temperature distribution T(x)

> T;

Surface temperature at x = 0.

> T0:=
subs(x = 0, T);

Surface temperature at x = L.

> TL:=
subs(x = L, T);

Find the location of the maximum temperature which occurs where

the temperature gradient is zero. Call the location xmax.

Verify that the maximum temperature occurs at the midpoint of

the plane wall when Tf1 = Tf2 and h1 = h2.

> xmax:=
simplify(solve(derT = 0, x));

> x_mid_point:=
simplify(subs(Tf1 = Tf2, h1 = h2, xmax));

Obtain expressions for the heat transfer rates at the two boundaries

x = 0 and x = L. Call these heat flow rates Q0 and QL respectively.

Find the sum of Q0 and QL.

> Q[0]:=
simplify(k*A*subs(x = 0, diff(rhs(sol), x)));

> Q[L]:=
simplify(- k*A*subs(x = L, diff(rhs(sol), x)));

> energy_balance:=
simplify(Q[0] + Q[L]);

Obtain the general expression for the maximum temperature.

> Tmax:=
subs(x = xmax, T);

The result is messy, but correct. Can you simplify the result?