ME 353 Heat Transfer 1

M.M. Yovanovich

CARTPOISS4.MWS

Solution of Poisson equation in plane wall with Robin boundary conditions at both boundaries.

The plane wall has thickness and constant thermal conductivity . The volumetric heat sources are constant and uniform at strength . The boundary at is heated by a fluid at temperature through a constant and uniform heat transfer coefficient , while the boundary at is cooled by a fluid whose temperature is denoted through a uniform and constant heat transfer coefficient .

Obtain the temperature distribution, and the heat transfer rates out of the wall at and . Also find the location of the maximum temperature, and a relation for the maximum temperature.

> restart:

Poisson Equation and Its Solution.

> ode:= diff(T(x), x$2) = - P/k;

> sol:= dsolve(ode, T(x));

Define the temperature and its derivative for application of the Robin boundary conditions.

> T:= rhs(sol); derT:= diff(T,x);

Robin Boundary Conditions.

> bc1:= subs(x=0, derT) + h[1]/k*(Tf1 - subs(x=0, T)) = 0;

> bc2:= subs(x=L, derT) + h[2]/k*(subs(x=L, T) - Tf2) = 0;

Solve for constants of integration.

> consts:= solve({bc1,bc2}, {_C1,_C2}):

Assign the constants of integration to get the temperature distribution.

> assign(consts):

> Temp:=expand(T):

Heat transfer rates at the two boundaries.

> Q[0]:= expand(k*A*subs(x=0, diff(Temp,x)));

> Q[L]:= expand(- k*A*subs(x=L, diff(Temp,x)));

Check the result by addition of the two relations.

> Q[total]:= Q[0] + Q[L];

The total heat transfer rate from both boundaries is equal to the heat generation rate. The temperature distribution is correct.

Location of the maximum temperature.

> x[max]:= simplify(solve(diff(Temp,x) = 0, x));

Alternative simpler form for the location of maximum temperature.

> x[max]:= L/2*(1 + k*(Tf2-Tf1)/(P*L^2) + k/(h[2]*L))/(1 + k/(h[1]*L) + k/(h[2]*L));

Verification of the above relation for the symmetry case where the two fluid temperatures and the two heat transfer coefficients are equal.

> x2[max]:= simplify(subs(h[1] = h, h[2] = h, Tf1 = Tf, Tf2 = Tf, x[max]));

This is the expected result. Also check the two heat transfer rates.

> Q2[0]:= simplify(subs(h[1]=h, h[2]=h, Tf1=Tf, Tf2=Tf, Q[0]));

> Q2[L]:= simplify(subs(h[1]=h, h[2]=h, Tf1=Tf, Tf2=Tf, Q[L]));

Both boundary heat transfer rates satisfy the symmetry condition.