ME 353 Heat Transfer 1

M.M. Yovanovich

CARTLAP2.MWS

_____________________________________________

Total Thermal Resistance of Plane Wall With Convection

Heating and Cooling.

Derivation and solution of Laplace equation in a plane wall

of thermal conductivity k which is assumed to be constant.

The boundary at x = 0 is heated by a fluid at temperature Tf1

through the heat transfer coefficient h1, and the boundary at

x = L is cooled by a fluid at temperature Tf2 < Tf1 through the

heat transfer coefficient h2.

Find the overall thermal resistance of this system defined as

R = (Tf1 - Tf2)/Q.

_________________________________________________

> restart:

> Q[x]:= - k*A*diff(T(x), x);
#Conduction rate into control volume dV = Adx.

> Q[x + dx]:= Q[x] + diff(Q[x], x)*dx;
#Conduction rate out of control volume dV = Adx.

> eq:= (Q[x] - Q[x + dx])/(k*A*dx) = 0;

> sol:= dsolve(eq, T(x)); rhs(sol);

> Ts1:= subs(x = 0, rhs(sol));
#Surface temperature at x = 0.

> Ts2:= subs(x = L, rhs(sol));
#Surface temperature at x = L.

> bc1:=
h1*(Tf1 - Ts1) + k*subs(x = 0, diff(rhs(sol), x)) = 0;

> bc2:=
- k*subs(x = L, diff(rhs(sol), x)) - h2*(Ts2 - Tf2) = 0;

> consts:=
solve({bc1, bc2}, {_C1, _C2});

> assign(consts);

> sol;

> Q:= - k*A*diff(rhs(sol), x);

Heat transfer rate through system. Maple does not simplify
the expression.

Overall thermal resistance of the system.

> R[total]:= simplify((Tf1 - Tf2)/Q);
R[total]:= expand(R[total]);

This looks better.

The overall resistance of the system consists of three resistances in series:

the two film resistances and the wall resistance.