ME 353 Heat Transfer 1

M.M. Yovanovich

CARTLAP1.MWS

____________________________________________

Thermal Resistance and Shape Factor of Plane Walls.

Derivation and solution of Laplace equation in a plane wall

of thermal conductivity k which is assumed to be constant.

Boundary conditions of the first kind: T(0) = T1 and

T(L) = T2 < T1.

Find the thermal resistance of this system defined as

R = (T1 - T2)/Q

and the shape factor defined by the relation

Q = k S (T1 - T2).

______________________________________________

> restart:

> Q[x]:= - k*A*diff(T(x), x);
#Conduction rate into control volume dV = Adx.

> Q[x + dx]:= Q[x] + diff(Q[x], x)*dx;
#Conduction rate out of control volume dV = Adx.

> eq:= (Q[x] - Q[x + dx])/(k*A*dx) = 0;

> sol:= dsolve(eq, T(x)); rhs(sol);

> bc1:=
subs(x = 0, rhs(sol)) = T1;
bc2:= subs(x = L, rhs(sol)) = T2;

> consts:=
solve({bc1, bc2}, {_C1, _C2});

> assign(consts);

> sol;

> Q:= - k*A*diff(rhs(sol), x);

Thermal resistance and shape factor of a plane wall.

> R:= simplify((T1 - T2)/Q);

> S:= simplify(Q/(k*(T1 - T2)));

Check the units of the thermal resistance and the shape factor.

> par_units:= {A = m^2, L = m, k = W/m/K};

> R_units:= subs(par_units, R);

> S_units:= subs(par_units, S);

>