ME 353 Heat Transfer 1

M.M. Yovanovich

P2MT90.MS

Problem 2 of Midterm Exam, October 1990.

____________________________________________

Plane wall of thickness D, thermal conductivity k, with

distributed volumetric heat sources qdot.

Left boundary is exposed to net incident flux q0pp,

and the right boundary is convectively cooled by a fluid

whose temperature is Tf, through a uniform heat transfer

coefficient h.

Steady-state, constant properties, negligible radiation

heat transfer.

_____________________________________________

> restart:

a) Derive differential equation by means of heat balance on

differential control volume.

Derive the boundary conditions at x = 0 and x = D by means

of heat balances on differential control volumes at the boundaries.

Using the notation of the exam and from Incropera and DeWitt.

> q[x]:= - k*A*diff(T(x), x);

> q[x + dx]:= q[x] + diff(q[x], x)*dx;

> q[gen]:= qdot*A*dx;

> eq:=
expand((q[x] + q[gen] - q[x + dx])/(k*A*dx)) = 0;

> q[`in`]:= qo_pp*A;

> q_pp:= - k*A*diff(T(x), x);

> bc0:= expand((q[`in`] - q_pp)/(k*A)) =0;

> q_ppConvection:= h*A*(T(x) - T[f]);

> bcD:= expand((q_pp - q_ppConvection)/(k*A)) = 0;

Summary of part a) in conventional form.

> ode:= diff(T(x), x, x) = - qdot/k;

> bc0:= diff(T(x), x) = - q0_pp/k;

> bcD:= diff(T(x), x) = - (h/k)*(T(x) - T[f]);

b) Obtain the temperature distribution in the plane wall.

> sol:= dsolve(ode, T(x));

> dersol:= diff(rhs(sol), x);

> bc1:=
subs(x = 0, dersol) = - q0_pp/k;

> bc2:=
subs(x = D, dersol) = - (h/k)*(subs(x = D, rhs(sol)) - T[f]);

> consts:= solve({bc1, bc2}, {_C1, _C2}):

> assign(consts);

> temp:= expand(sol);

Alternative form of the solution.

> temp2:= T[f] + (qdot*D + q0_pp)/h +
(1/2)*qdot*(D^2 - x^2)/k + q0_pp*(D - x)/k;

c) Determine the heat transfer rate per unit area at x = D

using three methods:

i) Fourier's rate equation,

ii) Newton's cooling law,

iii) Overall thermal energy balance.

> Q_D1:= expand(subs(x = D, - k*A*diff(rhs(temp), x)));

> Q_D2:= expand(subs(x = D, h*A*(rhs(temp) - T[f])));

> Q_D3:= expand(q0_pp*A + qdot*A*D);

All three methods give the same relation.