ME 353 Heat Transfer 1

M.M. Yovanovich

FEF96P3.MWS

________________________________________

Problem 3 of Final Examination, December 9, 1996.

See the problem statement.

_________________________________________

> restart:

Define the heat generation rate due to ohmic heating and the convection

loss for a wire of length L.

> Qgen:= Current^2*R_elect;

> #Units of Current are amperes.
#Units of R_elect are ohms.

> Qloss:= h*S*(Ts - Tf);

> #S is the total convection surface.

> #Ts = surface temperature and Tf = fluid temperature.

At thermal equilibrium, these two quantities are equal.

Solve for the current.

> rts:= solve(Qgen = Qloss, Current);
#There are two roots.

Take the positive root and substitute for the various parameters.

> Current1:= rts[1];

The electrical resistance of a wire of length L and area A and electrical

resistivity rhoe is

> R_elect:= rhoe*L/A;
#Units of electrical resistivity are ohm-m.

Define the wire surface and cross-section areas.

> S:= Pi*D*L; A:= Pi/4*D^2;

From the definition of the Nusselt number obtain the

heat transfer coefficient.

> h:= k*NuD/D;

Replace the Nusselt number by the general correlation

equation of Hilpert.

The correlation coefficients C and m depend on the range of the

Reynolds number.

> NuD:= C*ReD^m*Pr^(1/3);

> Current2:= Current1;

Define the Reynolds number.

> ReD:= rho*U*D/mu;

> Current3:= Current2;

The arbitrary wire length L can be removed by setting L = 1.

> Current4:= subs(L = 1, Current3);

Specify the air properties and the wire properties.

> air_prop:=
(k = 0.0300, cp = 1009, mu = 208.2*10^(-7),
rho = 0.9950, Pr = 0.700,Ts = 117, Tf = 37);

> wire:= (D = 0.6/1000, L = 1, rhoe = 16.67*10^(-6)/100);

For the Reynolds number range: 40 < ReD < 4000, the correlation coefficients

are C = 0.683, m = 0.466.

> corr_coef:= (C = 0.683, m = 0.466);

(a) Obtain relationship between the current and the air velocity.

> Current5:=
evalf(subs(air_prop, wire, corr_coef, Current4), 4);

> #The units of the velocity are m/s and
#for the current they are amperes.

(b) Calculate the current required when the air velocity is 30 m/s.

> Current6:= evalf(subs(U = 30, Current5), 4);

Check the value of the Reynolds number.

> ReD1:= evalf(subs(U = 30, air_prop, wire, ReD), 5);

The above value of the Reynolds number lies in the required range.