ME 353 Heat Transfer 1

M.M. Yovanovich

FEF96P1.MWS

_________________________________________

Problem 1 of Final Examination, December 9, 1996.

See the problem statement.

__________________________________________

> restart:

Specify the brick properties and dimensions.

Assume L1 < L2 < L3.

> brick:=
(L1 = 50/2000, L2 = 80/2000, L3 = 180/2000,
k = 1.0, rho = 2000, cp = 960);

Specify the conditions of the problem.

> case1:= (h = 60, Ti = 1500, Tf = 300, t = 60*60);

Define the three sets of Fourier and Biot numbers.

Use the half-thickness of each side as the characteristic lengths.

> Fo1:= alpha*t/L1^2; Fo2:= alpha*t/L2^2;
Fo3:= alpha*t/L3^2;

> Bi1:= h*L1/k; Bi2:= h*L2/k; Bi3:= h*L3/k;

Define the thermal diffusivity parameter.

> alpha:= k/(rho*cp);

(a) Can the lumped capacitance method be used to

calculate the cooling rate?

Check the magnitude of the Biot number.

> Bi_lumped:= h*V/A;

> V:= 2*L1*2*L2*2*L3;

> A:= 2*(L1*L2 + L1*L3 + L2*L3);

Calculate the Biot number based on the lumped capacitance model.

> Bi_lumped1:= evalf(subs(brick, case1, Bi_lumped), 4);

Since the value is much greater than 0.2, the lumped capacitance

method cannot be used in this problem.

(b) Compute the temperature at the center of the brick.

First compute the three values of the Fourier and Biot numbers

to see whether the first term approximation can be used.

> Fo_vals:=
evalf(subs(brick, case1, [Fo1, Fo2, Fo3]), 4);

> Bi_vals:=
evalf(subs(brick, case1, [Bi1, Bi2, Bi3]), 4);

Since all values of the Fourier number are greater than 0.2,

the first term can be used to give accurate results.

The superposition principle can be used. Therefore the

dimensionless temperature of the brick is equal to the

product of three plane wall solutions.

> phi['brick']:= phi1*phi2*phi3;

The general plane wall solution is according to the problem

statement.

> phi:=

A1*exp(- delta1^2*Fo)*cos(delta1*zeta);

> A1:=
2*sin(delta1)/(delta1 + sin(delta1)*cos(delta1));

> delta1:=
Pi/2/(1 + (Pi/2/sqrt(Bi))^n)^(1/n);

> n:= 2.139;

Dimensionless position is zeta = x/L where 0 <= zeta <= 1.

> 'zeta' = 'x/L';

Compute the three values of the eigenvalues corresponding to the lengths

L1, L2 and L3.

> delta_vals:=
[evalf(seq(subs(Bi = Bi_vals[j], delta1),
j = 1..3), 6)];

Compute the three values of the first Fourier coefficient A1.

> A1_vals:=
[evalf(seq(subs(delta1 = delta_vals[j], A1),
j = 1..3), 6)];

Compute the three values of the dimensionless temperature.

Set zeta = 0 for each plane wall solution.

> phi_vals:=
[evalf(seq(subs(brick, case1, zeta = 0,
Fo = Fo_vals[j], Bi = Bi_vals[j], phi),
j = 1..3), 6)];

Compute the dimensionless temperature at the brick center after 6 minutes

of cooling by taking the product of the three plane wall results.

Compute the temperature at the brick center.

> phi_brick:=
evalf(phi_vals[1]*phi_vals[2]*phi_vals[3], 4);

> T_center:= Tf + (Ti - Tf)*phi0;

> T_centerK:=
evalf(subs(case1, phi0 = phi_brick, T_center), 4);

> T_centerC:= evalf(T_centerK - 273.2, 4);

(c) The smallest dimension controls the cooling rate of the brick.

Observe that the dimensionless temperature of the brick is closer to

the value for the thinnest plane wall.

The cooling rate is controlled by the exponential function which depends

strongly on the Fourier number.

Summary of the results.

> `Bi lumped` = Bi_lumped1;

> `Fourier numbers` = Fo_vals;

> `Biot numbers` = Bi_vals;

> `eigenvalues` = delta_vals;

> `Fourier coefficients` = A1_vals;

> `phi values` = phi_vals;

> `phi brick` =phi_brick;

> `T_brick_center_K` = T_centerK*K;

> `T_brick_center_C` = T_centerC*C;