Separation of Variables Method Diffusion Equation

in Circular Cylinder Coordinates

M.M. Yovanovich

SEPVARDIFFCYL1.MWS

Separation of variables method applied to the one-dimensional diffusion equation in circular cylinder coordinates. The partial differential equation will be separated into three sets of independent ordinary differential equations by the substitution where and are independent space and time functions.

Diffusion equation in circular cylinder coordinates.

> restart:

> PDE:= diff(U(r,t),r,r) + diff(U(r,t),r)/r - diff(U(r,t),t)/alpha = 0;

> U(r,t):= R(r)*tau(t);

> ODE:= expand(PDE/U(r,t));

We observe that the substitution has separated the partial differential equation into three terms. The first two terms are dependent on only and the third term depends on only. This identity must hold for all values of and .

The identity is satisfied by setting the sum of the first two terms and the third term to i) , ii) and iii) .

These three options will be examined below.

Option 1: ODEs and their Solutions.

> ode11:= expand(R(r)*(op(1, op(1, ODE)) + op(2, op(1, ODE)))) = 0;

> ode12:= -tau(t)*op(3, op(1,ODE)) = 0;

> sol11:= subs(_C1 = A, _C2 = B, dsolve(ode11, R(r)));

> sol12:= subs(_C1 = C, dsolve(ode12, tau(t)));

One Solution of the Diffusion Equation.

> sol1Diffusion:= rhs(sol11)*rhs(sol12);

The first solution of the one-dimensional diffusion equation is independent of time and logarithmic in .

The constant of integration can be combined with the other two constants of integration.

Option 2: ODEs and their Solutions.

> ode21:= expand(R(r)*(op(1, op(1, ODE)) + op(2, op(1, ODE)) + lambda^2)) = 0;

> ode22:= expand(-alpha*tau(t)*(op(3, op(1,ODE)) - lambda^2)) = 0;

> sol21:= subs(_C1 = A, _C2 = B, dsolve(ode21, R(r)));

> sol22:= subs(_C1 = C, dsolve(ode22, tau(t)));

A Second Solution of the Diffusion Equation.

> sol2Diffusion:= rhs(sol21)*rhs(sol22);

The second solution of the one-dimensional diffusion consists of the product of Bessel functions of the first and second kinds of order 0 and an exponential time function.

The Bessel functions are periodic. The time function decreases with increasing time. The constant of integration can be combined with the other two constants of integration.

Option 3: ODEs and their Solutions.

> ode31:= expand(R(r)*(op(1, op(1, ODE)) + op(2, op(1, ODE)) - lambda^2)) = 0;

> ode32:= expand(-alpha*tau(t)*(op(3, op(1,ODE)) + lambda^2)) = 0;

> sol31:= subs(_C1 = A, _C2 = B, dsolve(ode31, R(r)));

> sol32:= subs(_C1 = C, dsolve(ode32, tau(t)));

A Third Solution of the Diffusion Equation.

> sol3Diffusion:= rhs(sol31)*rhs(sol32);

The third solution of the one-dimensional diffusion consists of the product of modified Bessel functions of the first and second kinds of order 0 and an exponential time function.

The modified Bessel functions are non-periodic. The time function increases with increasing time.

The constant of integration can be combined with the other two constants of integration.

Summary of the three independent solutions of the one-dimensional diffusion equation.

> sol_Diffusion1:= subs(C = 1, sol1Diffusion);

> sol_Diffusion2:= subs(C = 1, sol2Diffusion);

> sol_Diffusion3:= subs(C = 1, sol3Diffusion);

The two constants of integration and and will be determined by the homogeneous boundary conditions of the first, second and third kinds, respectively, and the initial condition.