Separation of Variables Method

Circular Cylinder Coordinates

M.M. Yovanovich

SEPVARCYLIND1.MWS

Separation of variables method applied to two-dimensional Laplace equation in circular cylinder coordinates. The partial differential equation is . The partial differential equation can be separated into three sets of independent second-order differential equations by the substitution where and are independent functions.

> restart:

Laplace equation in circular cylinder (polar) coordinates.

> PDE:= diff(U(r,z),r,r) + diff(U(r,z),r)/r + diff(U(r,z),z,z) = 0;

> U(r,z):= R(r)*Z(z);

> PDE2:= PDE;

> ODE:= expand(PDE2/U(r,z));

We observed that the first two terms are functions of only and the third term is a function of only. This identity must hold for all values of the space coordinates and . This can be achieved by setting the first two terms and the third term to i) zero, or two constants with different signs such as ii) or iii) . We will examine the three options.

Option 1: ODEs and their solutions.

> ode11:= expand(R(r)*(op(1,op(1,ODE)) + op(2,op(1,ODE)))) = 0;

> ode12:= Z(z)*op(3, op(1,ODE)) = 0;

> sol11:= subs(_C1 = A, _C2 = B, dsolve(ode11, R(r)));

> sol12:= subs(_C1 = C, _C2 = D, dsolve(ode12, Z(z)));

One Solution of the Laplace Equation.

> sol1Laplace:= rhs(sol11)*rhs(sol12);

We observe that the solution is logarithmic in and linear in .

Option 2: ODEs and their Solutions.

> ode21:= expand(R(r)*(op(1,op(1,ODE)) + op(2,op(1,ODE)) + lambda^2)) = 0;

> ode22:= expand(Z(z)*(op(3, op(1,ODE)) - lambda^2)) = 0;

> sol21:= subs(_C1 = A, _C2 = B, dsolve(ode21, R(r)));

> sol22:= subs(_C1 = C, _C2 = D, dsolve(ode22, Z(z)));

A Second Solution of the Laplace Equation.

> sol2Laplace:= rhs(sol21)*rhs(sol22);

The solution consists of Bessel functions of the first kind of order zero, and exponential functions in . The Bessel functions and are periodic functions.

Option 3: ODEs and their Solutions.

> ode31:= expand(R(r)*(op(1,op(1,ODE)) + op(2,op(1,ODE)) - lambda^2)) = 0;

> ode32:= expand(Z(z)*(op(3, op(1,ODE)) + lambda^2)) = 0;

> sol31:= subs(_C1 = A, _C2 = B, dsolve(ode31, R(r)));

> sol32:= subs(_C1 = C, _C2 = D, dsolve(ode32, Z(z)));

A Third Solution of the Laplace Equation.

> sol3Laplace:= rhs(sol31)*rhs(sol32);

The solution consists of modified Bessel functions of the first kind of order zero, and trigonometric functions in . The modified Bessel functions and are non-periodic functions.

Summary of the three independent solutions of the two-dimensional Laplace equation.

> sol_Laplace1:= sol1Laplace;

> sol_Laplace2:= sol2Laplace;

> sol_Laplace3:= sol3Laplace;

The constants of integration and will be determined by the homogeneous boundary conditions of the first, second or third kind.